Menghitung Jumlah Teks Dengan Pola Huruf Besar Kecil

Menghitung jumlah teks tertentu dengan fungsi COUNTIF atau COUNTIFS adalah fungsi yang sering dipakai dan berjalan baik, namun keduanya tidak bisa dipakai dengan pola huruf besar kecil, maka kedua fungsi itu tidak bisa dipakai untuk melakukan permasalahan ini. Solusinya adalah dengan menggunakan fungsi EXACT untuk membandingkan teks dengan pola huruf besar kecilnya dan dengan fungsi SUMPRODUCT yang akan menjumlahkannya.

{getToc} $title={Daftar Isi}

Fungsi EXACT

Fungsi ini bekerja untuk membandingkan teks dengan pola huruf besar kecil. Jika kedua argumen antara text1 dengan text2 cocok dari teks dan pola besar kecilnya, maka akan menghasilkan TRUE. Jika ada satu huruf saja yang tidak sama besar kecilnya akan menghasilkan FALSE. Contohnya seperti dibawah ini

=EXACT("excel";"excel")
// menghasilkan TRUE


=EXACT("excel";"Excel")
// menghasilkan FALSE


=EXACT("excel";"EXCEL")
// menghasilkan FALSE

Contoh Formula

Admin membuatkan contoh dengan membuat rumus pada kolom D dan beberapa data di B3:B12.

Dalam contoh ini kita menghitung berapa jumlah setiap teks di kolom D3:D4 yang dibandingkan dengan data pada kolom B3:B12, dan penghitungan ini harus peka terhadap huruf besar kecil. Rumus yang akan kita tuliskan pada E3 adalah:

=SUMPRODUCT(--EXACT(D3;$B$3:$B$12))

Penggunaan Fungsi EXACT

Dalam penggunaan fungsi EXACT disini untuk membandingkan setiap teks di kolom D dengan data B3:B12.

--EXACT(D3;$B$3:$B$12)

Fungsi EXACT akan membandingkan teks di D3 ("excel") dengan semua teks di B3:B12. Karena kita memberikan beberapa nilai dalam argumen kedua yaitu B3:B12, maka argumen ini mengembalikan banyak hasil. Secara menyeluruh, proses ini mempunyai 10 nilai dari setiap teks yang berada pada B3:B12. Jika kita debug formula akan tampil seperti ini:

={TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}

Setiap teks yang benar-benar cocok akan menghasilkan nilai TRUE, yaitu teks "excel" pada kolom B3:B12. Dan setiap teks yang tidak cocok akan menghasilkan nilai FALSE. Karena kita akan menghitung menggunakan SUMPRODUCT, maka kita tambahkan minus dua (--) pada fungsi EXACT agar yang menghasilkan nilai TRUE diubah menjadi angka 1 dan yang FALSE menjadi angka 0. Array yang tersimpan akan terlihat seperti ini:

={1;0;0;0;0;0;1;0;0;0}

Penggunaan Fungsi SUMPRODUCT

Fungsi SUMPRODUCT digunakan untuk menjumlahkan array yang dihasilkan EXACT. Fungsi SUMPRODUCT mampu menangani operasi array secara asli tanpa harus menekan Ctrl+Shift+Enter. Contoh array yang akan dijumlahkan dengan SUMPRODUCT.

=SUMPRODUCT({1;0;0;0;0;0;1;0;0;0})

Dengan hanya satu baris, SUMPRODUCT mampu menjumlahkan semua angka didalamnya dan menghasilkan nilai 2.